home *** CD-ROM | disk | FTP | other *** search
/ 1,000 Game Levels 2 / 1,000 Game Levels 2.iso / DOSCARD / SLOT2_42.ZIP / SLOTMACH.BAS < prev    next >
BASIC Source File  |  1995-09-22  |  6KB  |  146 lines
  1. 10 M=25
  2. 20 RANDOMIZE INT(VAL(MID$(TIME$,7,2)))
  3. 30 WIDTH 80:CLS:GOSUB 1260
  4. 40 REM 'CONVERTED FOR IBM-PC FROM 101 BASIC COMPUTER GAMES BY DIGITAL
  5. 50 REM 'EQUIPMENT CORP. SUBMITTED TO DIGITAL BY ROB HOFFBERG OF ROSLYN N.Y.
  6. 60 REM 'AUTHOR UNKNOWN
  7. 70 CLS
  8. 80 PRINT "OK ";N$;" Here are the odds:"
  9. 90 LOCATE 5,10:PRINT "SYMBOL     HOW MANY     PAYOUT"
  10. 100 LOCATE 6,10:PRINT "111111111111111111111111111111"
  11. 110 LOCATE 7,10:PRINT "CHERRY        3         $2.00"
  12. 120 LOCATE 8,10:PRINT "CHERRY        2         $1.00   LEFT & MID WINDOWS ONLY!"
  13. 130 LOCATE 9,10:PRINT "CHERRY        1         $0.50   LEFT WINDOW ONLY!"
  14. 140 LOCATE 11,10:PRINT "PLUM          3         $5.00"
  15. 150 LOCATE 12,10:PRINT "ORANGE        3         $7.50"
  16. 160 LOCATE 13,10:PRINT "*BAR*         3        $10.00"
  17. 170 LOCATE 15,10:PRINT "      LEMONS ALWAYS LOOSE"
  18. 180 LOCATE 20,5:PRINT "When the message PULL appears, press ENTER to PULL."
  19. 190 LOCATE 21,5:PRINT "Or type END to end the session."
  20. 200 LOCATE 23,5:PRINT "When you are ready to begin press ENTER.";:INPUT Z9$
  21. 210 L$=CHR$(186)
  22. 220 S$=CHR$(205)
  23. 230 B$=CHR$(186)
  24. 240 DIM W$(4)
  25. 250 W$(1)="CHERRY":W$(2)="      ":W$(3)="*BAR* ":W$(4)=" PLUM "
  26. 260 REM "WHEEL ONE
  27. 270 DIM V$(7)
  28. 280 V$(1)="ORANGE":V$(2)=" PLUM ":V$(3)="LEMON ":V$(4)="*BAR* "
  29. 290 V$(7)="CHERRY":V$(5)="CHERRY":V$(6)="CHERRY"
  30. 300 REM "WHEEL TWO
  31. 310 DIM V1$(7)
  32. 320 V1$(1)="*BAR* ":V1$(2)="LEMON ":V1$(3)=" PLUM "
  33. 330 V1$(4)="CHERRY":V1$(5)=" PLUM ":V1$(6)="ORANGE":V1$(7)="CHERRY"
  34. 340 REM "WHEEL THREE
  35. 350 DIM V3$(5)
  36. 360 V3$(1)=" PLUM ":V3$(2)="*BAR* ":V3$(3)="CHERRY":V3$(4)="LEMON "
  37. 370 V3$(5)="ORANGE"
  38. 380 CLS
  39. 390 Y=16:FOR X=1 TO 18:LOCATE X,Y:PRINT S$:NEXT X
  40. 400 X=18:FOR Y=17 TO 50:LOCATE X,Y:PRINT B$:NEXT Y
  41. 410 Y=51:FOR X=18 TO 1 STEP-1:LOCATE X,Y:PRINT S$:NEXT X
  42. 420 X=1:FOR Y=50 TO 17 STEP-1:LOCATE X,Y:PRINT L$:NEXT Y
  43. 430 REM "ARM
  44. 440 LOCATE 14,52:PRINT "/";
  45. 450 Y=52:FOR X=13 TO 8 STEP-1:LOCATE X,Y:PRINT "//";:Y=Y+1:NEXT X
  46. 460 FOR X=7 TO 6 STEP-1:LOCATE X,57:PRINT STRING$(3,196):NEXT X
  47. 470 LOCATE 13,28:PRINT "P A Y O U T":LOCATE 14,33
  48. 480 X=15:FOR Y=24 TO 42:LOCATE X,Y:PRINT L$:NEXT Y
  49. 490 FOR X=15 TO 17:LOCATE X,43:PRINT S$:NEXT X
  50. 500 FOR Y=42 TO 24 STEP-1:LOCATE 17,Y:PRINT B$:NEXT Y
  51. 510 FOR X=17 TO 15 STEP-1:LOCATE X,23:PRINT S$:NEXT X
  52. 520 REM "******LEFT WINDOW*****
  53. 530 FOR Y=18 TO 26:LOCATE 5,Y:PRINT L$:NEXT Y
  54. 540 FOR X=5 TO 7:LOCATE X,27:PRINT S$:NEXT X
  55. 550 FOR Y=26 TO 18 STEP-1:LOCATE 7,Y:PRINT B$:NEXT Y
  56. 560 FOR X=7 TO 5 STEP-1:LOCATE X,18:PRINT S$:NEXT X
  57. 570 REM "*****MID WINDOW*****
  58. 580 FOR Y=30 TO 37:LOCATE 5,Y:PRINT L$:NEXT Y
  59. 590 FOR X=5 TO 7:LOCATE X,38:PRINT S$:NEXT X
  60. 600 FOR Y=37 TO 30 STEP-1:LOCATE 7,Y:PRINT B$:NEXT Y
  61. 610 FOR X=7 TO 5 STEP-1:LOCATE X,29:PRINT S$:NEXT X
  62. 620 REM "*****RIGHT WINDOW*****
  63. 630 FOR Y=41 TO 48:LOCATE 5,Y:PRINT L$:NEXT Y
  64. 640 FOR X=5 TO 7:LOCATE X,49:PRINT S$:NEXT X
  65. 650 FOR Y=48 TO 41 STEP-1:LOCATE 7,Y:PRINT B$:NEXT Y
  66. 660 FOR X=7 TO 5 STEP-1:LOCATE X,40:PRINT S$:NEXT X
  67. 670 REM "DO YOU PULL OR END
  68. 680 LOCATE 21,24:PRINT "YOU NOW HAVE ";:PRINT USING "$$###.##";M
  69. 690 LOCATE 22,30:PRINT "PULL/END";:INPUT A$
  70. 700 LOCATE 16,24:PRINT E$;E$;E$;E$;"   "
  71. 710 E$="    ":LOCATE 6,19:PRINT E$;E$:LOCATE 6,30:PRINT E$;E$:LOCATE 6,41:PRINT E$;E$
  72. 720 IF A$="END" OR A$="E" THEN 1250
  73. 730 REM " * PICK THE WHEELS
  74. 740 FOR I=1 TO 2:Z(I)=INT((RND*7)+1):NEXT I
  75. 750 Z(3)=INT((RND*5)+1)
  76. 760 REM "***** ROLL ALL WINDOWS AND PICK LEFT *****
  77. 770 FOR X=1 TO 10:FOR Y=1 TO 4:LOCATE 6,20:PRINT W$(Y)
  78. 780 LOCATE 6,31:PRINT W$(Y):LOCATE 6,42:PRINT W$(Y):NEXT Y:NEXT X
  79. 790 LOCATE 6,20:PRINT V$(Z(1))
  80. 800 SOUND 200,2
  81. 810 REM " ***** ROLL MID AND RIGHT AND PICK MID *****
  82. 820 FOR X=1 TO 15:FOR Y=1 TO 4
  83. 830 LOCATE 6,31:PRINT W$(Y):LOCATE 6,42:PRINT W$(Y):NEXT Y:NEXT X
  84. 840 LOCATE 6,31:PRINT V1$(Z(2))
  85. 850 SOUND 200,2
  86. 860 REM "***** ROLL RIGHT AND PICK RIGHT *****
  87. 870 FOR X=1 TO 20:FOR Y=1 TO 4
  88. 880 LOCATE 6,42:PRINT W$(Y):NEXT Y:NEXT X
  89. 890 LOCATE 6,42:PRINT V3$(Z(3))
  90. 900 SOUND 200,2
  91. 910 REM "DO I HAVE 3 OF A KIND
  92. 920 IF V$(Z(1))<>V1$(Z(2)) THEN 1050
  93. 930 IF V1$(Z(2))<>V3$(Z(3)) THEN 1050
  94. 940 IF V$(Z(1))<>"CHERRY" THEN 960
  95. 950 LOCATE 16,27:PRINT "YOU WIN $2.00":M=M+2:GOTO 670
  96. 960 IF V$(Z(1))<>" PLUM " THEN 980
  97. 970 LOCATE 16,27:PRINT "YOU WIN $5.00":M=M+5:GOTO 670
  98. 980 IF V$(Z(1))<>"ORANGE" THEN 1000
  99. 990 LOCATE 16,27:PRINT "YOU WIN $7.50":M=M+7.5:GOTO 670
  100. 1000 IF V$(Z(1))<>"*BAR* " THEN 1020
  101. 1010 LOCATE 16,27:PRINT "YOU WIN $10.00":M=M+10:GOTO 670
  102. 1020 REM "LEMONS
  103. 1030 LOCATE 16,28:PRINT "LEMONS LOSE!":M=M-.25:GOTO 670
  104. 1040 REM
  105. 1050 REM "DO I HAVE CHERRIES
  106. 1060 IF V$(Z(1))<>"CHERRY" THEN 1140
  107. 1070 IF V1$(Z(2))<>"CHERRY" THEN 1120
  108. 1080 REM
  109. 1090 REM "2 CHERRIES
  110. 1100 LOCATE 16,27:PRINT "YOU WIN $1.00":M=M+1:GOTO 670
  111. 1110 REM
  112. 1120 REM " 1 CHERRY
  113. 1130 LOCATE 16,27:PRINT "YOU WIN $0.50":M=M+.5:GOTO 670
  114. 1140 REM
  115. 1150 REM " GOT SCHMALTZ
  116. 1160 ON Z(3) GOSUB 1180,1190,1200,1210,1220,1230,1240
  117. 1170 M=M-.25:GOTO 670
  118. 1180 LOCATE 16,25:PRINT "TRY BINGO INSTEAD":RETURN
  119. 1190 LOCATE 16,25:PRINT "HA HA YOU LOSE":RETURN
  120. 1200 LOCATE 16,25:PRINT "ZILCH-O":RETURN
  121. 1210 LOCATE 16,25:PRINT "TRY AGAIN SUCKER":RETURN
  122. 1220 LOCATE 16,25:PRINT "TRY VEGAS INSTEAD":RETURN
  123. 1230 LOCATE 16,25:PRINT "YOU GOT SCHMALTZ":RETURN
  124. 1240 LOCATE 16,25:PRINT "BACK TO STAR TREK":RETURN
  125. 1250 FOR I=1 TO 30:LOCATE 16,26:PRINT "BUY-BUY ";N$:NEXT I:END
  126. 1260 'COLOR 3
  127. 1270 KEY OFF:CLS
  128. 1280 FOR J=2 TO 22
  129. 1290 LOCATE 2,2:PRINT CHR$(201):LOCATE 2,79:PRINT CHR$(187)
  130. 1300 LOCATE 23,2:PRINT CHR$(200):LOCATE 23,79:PRINT CHR$(188)
  131. 1310 LOCATE J,2:PRINT CHR$(186)
  132. 1320 LOCATE J,79:PRINT CHR$(186)
  133. 1330 NEXT J
  134. 1340 FOR J=3 TO 78
  135. 1350 LOCATE 2,J:PRINT CHR$(205)
  136. 1360 LOCATE 23,J:PRINT CHR$(205)
  137. 1370 NEXT J
  138. 1380 'COLOR 2
  139. 1390 LOCATE 4,4:PRINT "W E L C O M E  T O . . ."
  140. 1400 LOCATE 8,30:PRINT "I B M ' S  C A S I N O"
  141. 1410 LOCATE 17,4:PRINT "Today you will lose your money at IBM's famous slot machine."
  142. 1420 LOCATE 18,4:PRINT "You have been given a credit line of $25.00. Therefore at 25 a pull you"
  143. 1430 LOCATE 19,4:PRINT "have a minimum of 100 pulls!"
  144. 1440 LOCATE 20,4:PRINT "By the way what is your name";:INPUT N$
  145. 1450 RETURN
  146.